openhabforum.de


https://openhabforum.de/

Fronius Brigde ist Online aber Symo Inverter Offline

https://openhabforum.de/viewtopic.php?t=3865

Seite 6 von 8

Re: Fronius Brigde ist Online aber Symo Inverter Offline

Verfasst: 18. Aug 2020 22:06
von Pepe1907
Hat es ein Grund dass du hinter dem Prozentzeichen keinen Punkt gesetzt hast?

Code: Alles auswählen

//http-Binding
Number      Current_L1      "Strom L1 [%2f A]"            { http="<[froniusrtd:30000:JSONPATH($.Body.Data.Current_AC_Phase_1)]" }
Kenne es nur so

Code: Alles auswählen

[code]//http-Binding
Number      Current_L1      "Strom L1 [%.2f A]"            { http="<[froniusrtd:30000:JSONPATH($.Body.Data.Current_AC_Phase_1)]" }
[/code]
damit er dir den Wert auf 2 Stellen hinterm Komma ausgibt.
violine21 hat geschrieben: ↑18. Aug 2020 21:25 Wollt's gerade schreiben. Hab ich vergessen, mit aufzuführen.
Das hatte ich bereits vorher mal installiert, darum ist es mir gerade nicht gleich eingefallen.
Zum Glück habe ich das noch als einfacher Handwerker selbst lösen können.


Bin dir und Udo sehr sehr sehr sehr dankbar!!!! Respekt an eure Hilfe, euer Wissen und eurer Arbeit die ihr in mich bzw uns investiert

Re: Fronius Brigde ist Online aber Symo Inverter Offline

Verfasst: 18. Aug 2020 23:43
von violine21
Pepe1907 hat geschrieben: ↑18. Aug 2020 22:06 damit er dir den Wert auf 2 Stellen hinterm Komma ausgibt.
Ja, Du hast Recht. Der Punkt fehlt. Die Unterschiede kann man in der Sitemap schön sehen.

Noch ein kleiner Hinweis: Du wirst feststellen, das der Wert vom SmartMeter und der Deines Hauptzählers nicht ganz zueinander passen.
Bei mir ist die gemessene Einspeiseleistung ohne Abweichung. Jedoch bei der bezogenen Leistung gibt es einen Unterschied.
Ich kontrolliere 1x pro Monat und stelle fest, das die Messwerte immer mehr ein wenig auseinander driften.
Es könnte mit Messtoleranzen erklärbar sein, keine Ahnung. Massgeblich relevant für die Abrechnung ist sowie so der Hauptzähler.

Vielen Dank für die Blumen! Die gebe ich gern an das Forum zurück!

Re: Fronius Brigde ist Online aber Symo Inverter Offline

Verfasst: 20. Aug 2020 16:11
von Pepe1907
Also die Fehlermeldung ist weiterhin da.

Code: Alles auswählen

2020-08-20 16:11:07.401 [hingStatusInfoChangedEvent] - 'fronius:powerinverter:mybridge:myinverter' changed from OFFLINE (COMMUNICATION_ERROR): Configuration is incorrect to ONLINE

2020-08-20 16:11:07.414 [hingStatusInfoChangedEvent] - 'fronius:powerinverter:mybridge:myinverter' changed from ONLINE to OFFLINE (COMMUNICATION_ERROR): Configuration is incorrect

Diese Rule scheint zu funktionieren ist aber in 3 Schritten gemacht, die man evtl abkürzen kann?
Total_Energy gibt die ges. erzeugt Leistung der Solaranlage in mWh an.
Energieeinspeisung die ges. eingespeiste Energie in kWh.

Code: Alles auswählen

rule "Ertrag gesamt"
when
   		Item einspeisung_kwh changed
then 
		 direkt_verb.postUpdate(((Total_Energy.state as Number * 1000) - einspeisung_kwh.state as Number) * 25 / 100 )
		 direkt_eing.postUpdate(einspeisung_kwh.state as Number * 123 / 1000)
		 ertrag_ges.postUpdate(direkt_verb.state as Number + direkt_eing.state as Number + 60 )  // Korrektur da er mir sonst 60€ zu wenig anzeigt
end
0,25 Euro sind die Stromkosten bei Bezug vom Netz
0,123 Euro bekommen wir für jede eingespeiste kWh.
Die 60€ sind nur zur Korrektur da er mir da er mir bei solarweb 60€ mehr anzeigt.
Möchte es mal über die Tage verfolgen und dann sehe ich ja ob ich da noch ein wenig anpassen sollte

Re: Fronius Brigde ist Online aber Symo Inverter Offline

Verfasst: 20. Aug 2020 19:11
von Pepe1907
Jetzt würde ich nur noch gern die Erträge des Tages, des Monats und des Jahres sehen können.
Ich habe als erstes Die gesamten Erträge persistiert.
rrd4j.perrist

Code: Alles auswählen

Strategies {
        everyMinute : "0 * * * * ?"
        everyHour   : "0 0 * * * ?"
        everyDay    : "0 0 0 * * ?"
        default = everyChange
}

Items {
        LocalWeatherAndForecast_Current_Regen : strategy = everyUpdate, restoreOnStartup
        gWetter* : strategy = everyMinute, everyChange, restoreOnStartup
		teichstand2 : strategy = everyMinute, restoreOnStartup
		beregnung : strategy = everyChange, restoreOnStartup
		teichauto : strategy = everyChange,restoreOnStartup
                rasennacht : strategy = everyChange, restoreOnStartup
                bezug_kwh : strategy = everyChange, restoreOnStartup
                einspeisung_kwh : strategy = everyChange, restoreOnStartup
                ertrag_ges : strategy = everyChange, restoreOnStartup
        
}
Dann habe ich schon die Tageserträge mittels Delta ermitteln lassen in einer Rule, ob es klappt sehe ich ja dann morgen.

Code: Alles auswählen

rule "Stromzaehler Verbrauch Tag"
 
when
        Item Day_Energy received update

then
        ertrag_tag.postUpdate(ertrag_ges.deltaSince(now.withTimeAtStartOfDay) as Number)

end
Jetzt weiß ich nur nicht wie ich die des laufenden Jahres bzw. Monat hinbekomme.
Vielen Dank für eure Hilfe

Re: Fronius Brigde ist Online aber Symo Inverter Offline

Verfasst: 20. Aug 2020 20:44
von nojo
zuerst, ich hoffe ich habe nichts in den Verlauf überlesen.....
hab selbst einen Fronius Symo 7.0-3-m installiert und eine kleine Regel bezüglich Tagesleistung und Jahresleistung geschrieben.

Code: Alles auswählen

rule "Produktion"
when
    Time cron "0 30 21 ? * * *"
then
    sendTelegram("bot1", "%.6s kW wurden Heute produziert", fronius_powerinverter_a7b6bf8b_inverterdatachanneldayenergy.state.toString)
    sendTelegram("bot1", "%.6s MW wurden dieses Jahr produziert", fronius_powerinverter_a7b6bf8b_inverterdatachannelyear.state.toString)
    
end
diese Regel schickt mir jeden Tag um 21:30 Uhr die Tages und Jahresleistung der Anlage.
Monatsleistung kommt per Mail von Fronius. kann über Solarweb--> Reports konfiguriert werden.

Re: Fronius Brigde ist Online aber Symo Inverter Offline

Verfasst: 20. Aug 2020 21:07
von violine21
Pepe1907 hat geschrieben: ↑20. Aug 2020 19:11 Jetzt weiß ich nur nicht wie ich die des laufenden Jahres bzw. Monat hinbekomme.
Vielen Dank für eure Hilfe
Ich hoffe, ich habe Dich nicht falsch verstanden aber diese Werte bekommst Du doch vom Symo:

Code: Alles auswählen

Number AC_Powery "aktuelle Leistung" { channel="fronius:powerinverter:mybridge:myinverter:inverterdatachannelpac" }
Number Day_Energy "Tages-Ertrag" { channel="fronius:powerinverter:mybridge:myinverter:inverterdatachanneldayenergy" }
Number Total_Energy "Gesamt-Ertrag" { channel="fronius:powerinverter:mybridge:myinverter:inverterdatachanneltotal" }
Number Year_Energy "Jahres-Ertrag" { channel="fronius:powerinverter:mybridge:myinverter:inverterdatachannelyear" }
Für den Monat musst Du dann immer am Monatsersten den Jahres-Ertrag persistieren und dann kannst Du auf diesen Wert
die laufende Differenz bilden und hast den Ertrag für den laufenden Monat.

Re: Fronius Brigde ist Online aber Symo Inverter Offline

Verfasst: 20. Aug 2020 21:17
von Pepe1907
violine21 hat geschrieben: ↑20. Aug 2020 21:07
Pepe1907 hat geschrieben: ↑20. Aug 2020 19:11 Jetzt weiß ich nur nicht wie ich die des laufenden Jahres bzw. Monat hinbekomme.
Vielen Dank für eure Hilfe
Ich hoffe, ich habe Dich nicht falsch verstanden aber diese Werte bekommst Du doch vom Symo:

Code: Alles auswählen

Number AC_Powery "aktuelle Leistung" { channel="fronius:powerinverter:mybridge:myinverter:inverterdatachannelpac" }
Number Day_Energy "Tages-Ertrag" { channel="fronius:powerinverter:mybridge:myinverter:inverterdatachanneldayenergy" }
Number Total_Energy "Gesamt-Ertrag" { channel="fronius:powerinverter:mybridge:myinverter:inverterdatachanneltotal" }
Number Year_Energy "Jahres-Ertrag" { channel="fronius:powerinverter:mybridge:myinverter:inverterdatachannelyear" }
Für den Monat musst Du dann immer am Monatsersten den Jahres-Ertrag persistieren und dann kannst Du auf diesen Wert
die laufende Differenz bilden und hast den Ertrag für den laufenden Monat.
Ich bekomme die geschaffene Energie. Aber auch nicht Monatsweise.
Würde gern die Wochen, Monats und Jahreserträge aus finanziellen Sicht einpflegen.
Tages Finanzen müssten ja ab morgen angezeigt werden mit

Code: Alles auswählen

ertrag_tag.postUpdate(ertrag_ges.deltaSince(now.withTimeAtStartOfDay)
Aber wochen, monats und jahreswert würde ich gern noch einpflegen

Re: Fronius Brigde ist Online aber Symo Inverter Offline

Verfasst: 20. Aug 2020 21:19
von Pepe1907
nojo hat geschrieben: ↑20. Aug 2020 20:44 zuerst, ich hoffe ich habe nichts in den Verlauf überlesen.....
hab selbst einen Fronius Symo 7.0-3-m installiert und eine kleine Regel bezüglich Tagesleistung und Jahresleistung geschrieben.

Code: Alles auswählen

rule "Produktion"
when
    Time cron "0 30 21 ? * * *"
then
    sendTelegram("bot1", "%.6s kW wurden Heute produziert", fronius_powerinverter_a7b6bf8b_inverterdatachanneldayenergy.state.toString)
    sendTelegram("bot1", "%.6s MW wurden dieses Jahr produziert", fronius_powerinverter_a7b6bf8b_inverterdatachannelyear.state.toString)
    
end
diese Regel schickt mir jeden Tag um 21:30 Uhr die Tages und Jahresleistung der Anlage.
Monatsleistung kommt per Mail von Fronius. kann über Solarweb--> Reports konfiguriert werden.
Vielen Dank für deine Lösung.
Würde nur gern wie im Beitrag davor erwähnt die finanziellen Aspekte einpflegen. Morgen kommt das 15" Touchscreen und dann möchte ich alles auf dem Touchscreen visualisiert haben

Re: Fronius Brigde ist Online aber Symo Inverter Offline

Verfasst: 20. Aug 2020 21:51
von udo1toni
Meine Rule:

Code: Alles auswählen

rule "PV-Anlage Update"
 when
    Item PV_Current received update
 then
    var String strCurr  = "Err; "
    var String strDay   = "Err; "
    var String strYear  = "Err; "
    var String strTotal = "Err; "
    logDebug("PV-update", "Start der Rule")
    if (PV_Current.state instanceof Number) {
        if (PV_Current.state > 1000)
            strCurr = String::format("%.2f kW; ", (PV_Current.state as Number) / 1000)
        else
            strCurr = PV_Current.state.format("%d W; ")
    }
    logDebug("PV-update", "strCurr = {}",strCurr)
    if (PV_DaySum.state instanceof Number) {
        if (PV_DaySum.state > 1000)
            strDay = String::format("%.2f kWh/d; ", (PV_DaySum.state as Number) / 1000)
        else
            strDay = PV_DaySum.state.format("%d Wh/d; ")
    }
    logDebug("PV-update", "strDay = {}",strDay)
    if (PV_YearSum.state instanceof Number) {
        if (PV_YearSum.state > 1000000)
            strYear = String::format("%.2f MWh/y; ", (PV_YearSum.state as Number) / 1000000)
        else if (PV_YearSum.state > 1000)
            strYear = String::format("%.2f kWh/y; ", (PV_YearSum.state as Number) / 1000)
        else
            strYear = PV_YearSum.state.format("%d Wh/y; ")
    }
    logDebug("PV-update", "strYear = {}",strYear)
    if (PV_Total.state instanceof Number) {
        if (PV_Total.state > 1000000)
            strTotal = String::format("%.2f MWh/t", (PV_Total.state as Number) / 1000000)
        else if (PV_Total.state > 1000)
            strTotal = String::format("%.2f kWh/t", (PV_Total.state as Number) / 1000)
        else
            strTotal = PV_Total.state.format("%d Wh/t")
    }
    logDebug("PV-update", "strTotal = {}",strTotal)
    MyPV.postUpdate(strCurr + strDay + strYear + strTotal)
end
Meine Items:

Code: Alles auswählen

Number PV_Current "Aktuelle Leistung [%0f W]" <inverter> (PV,PV_Graf) { http="<[froniusrtd:30000:JSONPATH($.Body.Data.PAC.Values.1)]" }
Number PV_DaySum  "Tagessumme [%0f Wh]"       <inverter> (PV,PV_Graf) { http="<[froniusrtd:30000:JSONPATH($.Body.Data.DAY_ENERGY.Values.1)]" }
Number PV_YearSum "Jahressumme [%0f Wh]"      <inverter> (PV)         { http="<[froniusrtd:30000:JSONPATH($.Body.Data.YEAR_ENERGY.Values.1)]" }
Number PV_Total   "Gesamtsumme [%0f Wh]"      <inverter> (PV)         { http="<[froniusrtd:30000:JSONPATH($.Body.Data.TOTAL_ENERGY.Values.1)]" }
String MyPV       "PV-Anlage [%s]"            <inverter> (PV)
Die Konfiguration des http-Caches:

Code: Alles auswählen

 froniusrtd.url=http://<ip.des.fronius.symo>/solar_api/v1/GetInverterRealtimeData.cgi?Scope=System
Die Werte werden von der Rule automatisch in Wh, kWh oder MWh angezeigt, und zwar aktueller Messwert, Tagessumme, Jahressumme und Gesamtertrag. Eine Monatssumme bilde ich in der UI nicht ab, allerdings sammle ich nachts die 5-Minuten-Messwerte der Anlage und schreibe sie in eine MariaDB-Tabelle. Die hat mir auch schon geholfen, wenn ich vergessen hatte, am 31.12. für die Steuer abzulesen. Aus den Werten kann ich aufaddierte Werte für beliebige Zeiträume bilden, das mache ich dann halt in SQL.


Gesendet von iPad mit Tapatalk

Re: Fronius Brigde ist Online aber Symo Inverter Offline

Verfasst: 20. Aug 2020 21:59
von violine21
Pepe1907 hat geschrieben: ↑20. Aug 2020 21:17 Aber wochen, monats und jahreswert würde ich gern noch einpflegen
Wie Udo schreibt, hilft Dir dabei eine Datenbank. Bei mir ist das auch eine MariaDB.
Ich nutze zur Visualisierung ein webseitenbasiertes System mit php-Scripten.
Darin stelle ich alles dar, was ich von der Anlage wissen muss:
- Autarkie
- Eigenverbrauchsquote
- Tages-, Monats,-Jahresverbrauch
Und das in Diagrammen meiner Wahl (z.B. Tortendiagramme)
Die Werte werden kurz vor Mitternacht in die Datenbank geschrieben.
Alle Zeiten sind UTC+02:00
Seite 6 von 8

Powered by phpBB® Forum Software © phpBB Limited

Deutsche Übersetzung durch phpBB.de