Gas-Zählerstand in manuell in openHab eingeben

[peter-pan]

So wie ich die Fehlermeldung(en) interpretiert habe, war einmal, die Tatsache, dass die erste Methode des "postUpdate" nur mit Strings funktionierte. Schau mal in der Doku (Link weiter oben). Da werden die Unterschiede zwischen den spezifischen und den generische Kommados (sendCommand, postUpdate) beschrieben. Generell sollten den spezifischen Kommandos der Vorzug gegeben werden.

Du kannst hier im Forum auch mal nach den Kommandos suchen. @udo1toni hat das an verschieden Stellen schon dokumentiert und die Unterschiede toll erklärt.

Beim zweiten Versuch war vermutlich der Grund, dass die Items (Gaszaehler_Stand + Gaszaehler_Heute) noch keine gültigen Werte (nur "NULL") enthalten haben.
Deshalb auch die 2 IF-Bedingungen mit der Gültigkeitsprüfung. Die Logs dazu sollten nur beim ersten mal erschienen sein

[Locke]

ja, die Bedingung ist nur beim ersten mal im Log erschienen.
Ich werde mir mal Dein Link und von @udo1toni die Erklärungen nochmal genauer ansehen und versuchen es zu verstehen.

Danke

[Locke]

Es ist von meiner Seite aus auch mit deiner Regel gelaufen, obwohl noch ein kleiner Schönheitsfehler (schon von mir) enthalten war:

Code: Alles auswählen

var  Number Einheit = 0.01
var Number Einheit = 0.01

Trotzdem läuft die Regel bei mir.

Was für einen Status hat denn das Item "Gaszaehler_Heute". Evtl. müsste man das noch initialisieren.

Also noch ein Versuch:

Code: Alles auswählen

var Number Letzter_abgelesener_Zaehlerstand = 1495.70
var Number Einheit = 0.01
var Number Gaspreis_Monat = 200.1 // € pro Jahr
var Number Gaspreis_Tag = 54.82191780821918 // ct pro Tag
var Number Gaspreis_kWh = 19.269 // ct pro kWh
var Number Gaspreis_zZahl = 0.9645 // z Zahl
var Number Gaspreis_Brennwert = 10.293 //Brennwert

rule "Increment Gas Meter"
when
   Item DummySchalter_TestSchalter changed from OFF to ON
then
     logInfo("Zählerstand","Test aktiviert 1") 
     if (!(Gaszaehler_Heute.state instanceof Number)) {
         logInfo("Zählerstand","Test Gaszaehler_Heute wird initialisiert")
         Gaszaehler_Heute.postUpdate(0)
     }
     if (!(Gaszaehler_Stand.state instanceof Number)) {
         logInfo("Zählerstand","Test Gaszaehler_Stand wird initialisiert")
         Gaszaehler_Stand.postUpdate(0)
     }
        
// Aktuellen Zaehlerstand setzten - die folgenden drei Zeilen auskommentieren und anschließend einen Zählimpuls auslösen damit das Regelwerk einmal durchlaufen wird!
/**/ if (Gaszaehler_Stand.state != NULL && Gaszaehler_Stand.state < Letzter_abgelesener_Zaehlerstand) {
        logInfo("Zählerstand","Bedingung erfüllt") 
          /**/ Gaszaehler_Stand.postUpdate(Letzter_abgelesener_Zaehlerstand) /**/ } 
        Gaszaehler_Heute.postUpdate(Gaszaehler_Heute.state as DecimalType + Einheit)
        Gaszaehler_Stand.postUpdate(Gaszaehler_Stand.state as DecimalType + Einheit)
        var Faktor = Gaspreis_zZahl * Gaspreis_Brennwert * Gaspreis_kWh 
        postUpdate(Gaskosten_Heute, ((Gaszaehler_Heute.state as DecimalType * Faktor) + Gaspreis_Tag) / 100) 
        logInfo("Zählerstand","Test aktiviert 2")
end

Jetzt wird also noch abgefragt, ob die Items auch tatsächlich einen Wert enthalten.

Hi Peter,
da Du mir letztes mal helfen konntest mit der Regel, dachte ich frag nochmal ob Du mir wieder helfen kannst.
Ich muß den Zählerstand (var Number Letzter_abgelesener_Zaehlerstand = 1495.70) aktualisieren und bekomme es nicht hin.
Kannst Du mir sagen welche drei Zeilen ich auskommentieren muss damit der von mir eingegebene Zählerstand übernommen wird ?

Danke

[Locke]

ich habe es jetzt mal auf einem Testsystem probiert, da funktioniert es sofort ohne etwas auszukommentieren, auch mehrmals mit der selben Regel.
Hat einer von euch eine Idee warum es auf dem Testsystem funktioniert und auf eigentlichen System nicht ?

[udo1toni]

Da wäre erst mal die Frage, welches System welches ist... Und warum überhaupt noch Systeme mit OH2.5.10 oder OH3.3.0? OH4 wäre 4.1.1 die aktuelle stable Version...
Letztlich musst Du definitiv nur den Zählerstand korrekt eingeben, und auch da wäre halt die Frage, bist Du sicher, dass Du die Daten korrekt eingibst (z.B. tatsächlich ein Punkt und kein Komma)? Hast Du das System mal neu gestartet?

Abgesehen davon, dass diese Art des Abgleichs halt... "ned so gut" ist...

[peter-pan]

Udo hat schon Recht.

t... "ned so gut"

1.Frage:
Welche OH-Version ist auf deinem "Problem-System" und wie sieht da die Regel aus ?
2.Frage:
Welche OH-Version ist auf deinem "Test-System" und wie sieht da die Regel aus ?

Ist der Wert jetzt nicht mehr 1495.70 ? Und geht es um diesen Wert ?

[Locke]

Hi,

@Udo

mit neu starten hatte ich probiert ohne erfolg.
das System 1, Raspberry Pi 4, 4GB RAM, openHAB 2.5.10 läuft nur nebenher, habe ein großen Teil schon auf das System 3, Raspberry Pi 4, 2GB RAM, openHAB 4.0.2 rübergezogen, es sind nur noch ein paar Tempwerte auf dem alten System, die nicht so relevant sind. Wenn das alles erledigt habe setze ich da neu auf.
Das System 3 wird demnächst aktualisiert sowie das System 3.4.5
Daten habe ich definitiv mit Punkt eingeben.

Abgesehen davon, dass diese Art des Abgleichs halt... "ned so gut" ist...

Warum ? Welche möglichkeit gibt es den Zählerstand anders anzupassen ?

@Peter

läuft auf System Raspberry Pi 4, 2GB RAM, openHAB 3.4.5
Das Testsystem ist auch Raspberry Pi 4, 2GB RAM, openHAB 3.4.5

Auf beiden Systemen ist die gleiche Regel und auf dem Testsystem hat es sofort ja funktioniert den Zählerstand anzupassen, leider nicht auf dem eigentlichen System.

Ist der Wert jetzt nicht mehr 1495.70 ? Und geht es um diesen Wert ?

Genau um diesen Wert geht es, da sich mein Wemos D1 mini an dem der KY025 hängt das zeitliche gesegnet hat,
habe ich einen neuen Wemos mit einem Backup bespielt und wollte jetzt den Wert "letzter abgelesener Zählerstand" aktualisieren.

Das System läuft einwandfrei, zählt auch den den Zählerstand hoch mit dem neuen Wemos.
Es stimmt halt der aktuelle Zählerstand mit dem System überein, deshalb möchte ihn anpassen.

Die Regel ist immer noch diese so wie Du sie mir damals verbessert hast.

Code: Alles auswählen

var Number Letzter_abgelesener_Zaehlerstand = 1495.70
var Number Einheit = 0.01
var Number Gaspreis_Monat = 200.1 // € pro Jahr
var Number Gaspreis_Tag = 54.82191780821918 // ct pro Tag
var Number Gaspreis_kWh = 19.269 // ct pro kWh
var Number Gaspreis_zZahl = 0.9645 // z Zahl
var Number Gaspreis_Brennwert = 10.293 //Brennwert

rule "Increment Gas Meter"
when
   Item DummySchalter_TestSchalter changed from OFF to ON
then
     logInfo("Zählerstand","Test aktiviert 1") 
     if (!(Gaszaehler_Heute.state instanceof Number)) {
         logInfo("Zählerstand","Test Gaszaehler_Heute wird initialisiert")
         Gaszaehler_Heute.postUpdate(0)
     }
     if (!(Gaszaehler_Stand.state instanceof Number)) {
         logInfo("Zählerstand","Test Gaszaehler_Stand wird initialisiert")
         Gaszaehler_Stand.postUpdate(0)
     }
        
// Aktuellen Zaehlerstand setzten - die folgenden drei Zeilen auskommentieren und anschließend einen Zählimpuls auslösen damit das Regelwerk einmal durchlaufen wird!
/**/ if (Gaszaehler_Stand.state != NULL && Gaszaehler_Stand.state < Letzter_abgelesener_Zaehlerstand) {
        logInfo("Zählerstand","Bedingung erfüllt") 
          /**/ Gaszaehler_Stand.postUpdate(Letzter_abgelesener_Zaehlerstand) /**/ } 
        Gaszaehler_Heute.postUpdate(Gaszaehler_Heute.state as DecimalType + Einheit)
        Gaszaehler_Stand.postUpdate(Gaszaehler_Stand.state as DecimalType + Einheit)
        var Faktor = Gaspreis_zZahl * Gaspreis_Brennwert * Gaspreis_kWh 
        postUpdate(Gaskosten_Heute, ((Gaszaehler_Heute.state as DecimalType * Faktor) + Gaspreis_Tag) / 100) 
        logInfo("Zählerstand","Test aktiviert 2")
end

[udo1toni]

Welche möglichkeit gibt es den Zählerstand anders anzupassen ?

Die einfachste Möglichkeit wäre vermutlich, ein Item zu definieren und den Zählerstand einzugeben, nicht als globale Variable, sondern über die UI.
In der Main UI gibt es sogar ganz reguläre Widgets für die Eingabe von Zahlenwerten.
Das Item wäre im Zweifel persistiert, hätte also auch nach einem Systemneustart sofort den letzten bekannten Wert.

Ich würde die Rule auch leicht anders gestalten. Hier mal noch die Version mit globaler Variable, aber umgestaltet:

Code: Alles auswählen

var    nCountTotalread = 1495.70                   // Letzte Ablesung
val            Einheit = 0.01                      // m³ pro Puls
val      Gaspreis_Jahr = 200.1                     // € pro Jahr
val       Gaspreis_Tag = 54.82191780821918         // ct pro Tag
val       Gaspreis_kWh = 19.269                    // ct pro kWh
val     Gaspreis_zZahl = 0.9645                    // z Zahl
val Gaspreis_Brennwert = 10.293                    // Brennwert

rule "Increment Gas Meter"
when
    Item DummySchalter_TestSchalter changed from OFF to ON
then
    var nCountToday = 0.0
    if(Gaszaehler_Heute.state instanceof Number)
        nCountToday = Gaszaehler_Heute.state as Number

    var nCountTotal = 0.0
    if(Gaszaehler_Stand.state instanceof Number)
        nCountTotal = Gaszaehler_Stand.state as Number

    if(nCountTotal < nCountTotalread) {
        logInfo("counter","Zählerstand {} geringer als Start Offset {}, setze letzen bekannten Zählerstand", nCountTotal, nCountTotalread) 
        nCountTotal = nCountTotalread
    }
    nCountToday += Einheit
    nCountTotal += Einheit
    Gaszaehler_Heute.postUpdate(nCountToday)
    Gaszaehler_Stand.postUpdate(nCountTotal)
    var Faktor = Gaspreis_zZahl * Gaspreis_Brennwert * Gaspreis_kWh 
    Gaskosten_Heute.postUpdate((nCountToday * Faktor + Gaspreis_Tag) / 100) 
end

1. Die Deklaration der Variablen als Number ist unnötig, solange man einen Dezimalbruch angibt
2. openHAB arbeitet asynchron. Es gibt keinerlei Garantie, dass ein Item seinen Status nicht ändert, genauso wenig wie es eine Garantie gibt, dass ein geschriebener Status sofort zur Verfügung steht.
   Es ist also sinnvoll, sämtliche Berechnungen bevorzugt in lokalen Variablen durchzuführen.
3. Daraus ergibt sich eine geänderte Abfrage ob eine gültige Zahl vorliegt. Statt das Item mit 0 zu initialisieren, wird die Variable mit 0.0 initialisiert (und wird damit automatisch als Number deklariert)
4. Falls das jeweilige Item eine gültige Zahl enthält, wird die Variable anschließend mit diesem Wert gefüllt.
5. Die Abfrage, ob der gespeicherte Total Zählerstand geringer ist als der zuletzt erfasste Zählerstand sollte eigentlich immer aktiv sein, dafür wird ja der Vergleich durchgeführt.
6. Anschließend wird jeweils der Wert von Einheit zu den Variablen addiert.
7. Die neuen Zählerstände werden in die Items geschrieben.

Daumenregel: Sobald man auf ein Item mehr als einmal zugreifen muss, sollte man eine (lokale) Variable verwenden.
Die Variable ist wesentlich schneller und sie ändert ihren Wert nicht ohne entsprechenden Befehl.

Wenn Du ein entsprechende Eingabe-Item für den Zählerstand angelegt hast, kannst Du diesen Zählerstand genauso in eine lokale Variable übernehmen.

Der Zähler liefert ja nur einen Impuls pro zehn Liter, insofern könntest Du auch einfach nur den Zählerstand hochzählen lassen und Dich auf die Persistence verlassen. Solange alle Impulse erfasst werden, kannst Du dann auch die Tagessumme leicht ermitteln

Code: Alles auswählen

val nDelta = Gaszaehler_Stand.deltaSince(now.with(LocalTime.MIDNIGHT))

liefert ab OH3.0 das Delta seit Mitternacht. Voraussetzung ist lediglich, dass der Zählerstand monoton wächst. Dann sähe die Rule so aus:

Code: Alles auswählen

val            Einheit = 0.01                      // m³ pro Puls
val      Gaspreis_Jahr = 200.1                     // € pro Jahr
val       Gaspreis_Tag = 54.82191780821918         // ct pro Tag
val       Gaspreis_kWh = 19.269                    // ct pro kWh
val     Gaspreis_zZahl = 0.9645                    // z Zahl
val Gaspreis_Brennwert = 10.293                    // Brennwert

rule "Increment Gas Meter"
when
    Item DummySchalter_TestSchalter changed from OFF to ON
then
    var nCountTotal = 0.0
    var nCountToday = 0.0
    var      Faktor = Gaspreis_zZahl * Gaspreis_Brennwert * Gaspreis_kWh 

    if(Gaszaehler_Stand.state instanceof Number)
        nCountTotal = Gaszaehler_Stand.state as Number

    nCountTotal += Einheit
    Gaszaehler_Stand.postUpdate(nCountTotal)
    Thread.sleep(300)
    nCountToday = Gaszaehler_Stand.deltaSince(now.with(LocalTime.MIDNIGHT))
    Gaszaehler_Heute.postUpdate(nCountToday)
    Gaskosten_Heute.postUpdate((nCountToday * Faktor + Gaspreis_Tag) / 100) 
end

Und das Item

Code: Alles auswählen

Gaszaehler_Stand

wird in der UI mit einer Eingabemöglichkeit versehen, so dass man den Zählerstand manuell korrigieren kann.
Das Thread.sleep(300) dient dazu, openHAB etwas Zeit zu geben, den neuen Wert zu persistieren. Dass das funktioniert, ist natürlich nicht gesichert. Auf der anderen Seite könnte man vermutlich gut damit leben, wenn die Anzeige mal um 10 Liter abweicht.

[peter-pan]

Udo hat das ja schön aufgebaut und das wäre vielleicht die bessere Lösung.

Aber, wenn ich das noch richtig verstehe, was ich da "fabriziert" habe, dann fragt die Regel, ob der Wert grösser als 1495.70 ist.

Vielleicht ist das der Grund ! Kann es sein, dass der Wert im Test-System vorher 0 oder kleiner als der Wert 1495.70 ?

Also sobald dieser Wert grösser als dein Grenzwert ist, wird dieser natürlich nicht mehr zurückgesetzt. Das ist in der Regel etwas "blöd verklausuliert".

Ich hab die Regel jetzt etwas verschlankt und die unnötigen Kommentare entfernt.

Code: Alles auswählen

var Letzter_abgelesener_Zaehlerstand = 1495.70
var Einheit = 0.01
var Gaspreis_Monat = 200.1 // € pro Jahr
var Gaspreis_Tag = 54.82191780821918 // ct pro Tag
var Gaspreis_kWh = 19.269 // ct pro kWh
var Gaspreis_zZahl = 0.9645 // z Zahl
var Gaspreis_Brennwert = 10.293 //Brennwert

rule "Increment Gas Meter"
when
   Item Dummy_pers_7 changed from OFF to ON
then
     if (!(Gaszaehler_Heute.state instanceof Number)) {
         logInfo("Zählerstand","Test Gaszaehler_Heute wird initialisiert")
         Gaszaehler_Heute.postUpdate(0)
     }
     if (!(Gaszaehler_Stand.state instanceof Number)) {
         logInfo("Zählerstand","Test Gaszaehler_Stand wird initialisiert")
         Gaszaehler_Stand.postUpdate(0)
     }
        
 if (Gaszaehler_Stand.state != NULL && Gaszaehler_Stand.state <= Letzter_abgelesener_Zaehlerstand) {
        Gaszaehler_Stand.postUpdate(Letzter_abgelesener_Zaehlerstand)  } 
        Gaszaehler_Heute.postUpdate(Gaszaehler_Heute.state as DecimalType + Einheit)
        Gaszaehler_Stand.postUpdate(Gaszaehler_Stand.state as DecimalType + Einheit)
        var Faktor = Gaspreis_zZahl * Gaspreis_Brennwert * Gaspreis_kWh 
        postUpdate(Gaskosten_Heute, ((Gaszaehler_Heute.state as DecimalType * Faktor) + Gaspreis_Tag) / 100) 
end

Eine weitere Regel, die aber im gleichen Rule-File sein sollte, da hier auch die globale Variable "var Letzter_abgelesener_Zaehlerstand = 1495.70" benutzt wird. Ansonsten müsstest du diese in einem separaten File nochmals definieren und bei Reset-Massnahmen wieder anpassen (in beiden Regeln).

Reset-Regel:

Code: Alles auswählen

rule "Reset Gas Meter"
  when
    Item Dummy_pers_6 changed from OFF to ON
  then
    Gaszaehler_Stand.postUpdate(Letzter_abgelesener_Zaehlerstand)
    logInfo("Reset Zählerstand","Zählerstand ist {}", Gaszaehler_Stand.state.toString )
end

Bitte beachte, das die beiden Regeln unterschiedliche Dummy-( Trigger) Schalter haben.

So jetzt geh' ich wieder in den Garten. Ist grad schönes Wetter und es macht richtig Laune Vorbereitungen für's Frühjahr zu machen.

Wenn's klappt gib Bescheid, wenn's nicht klappt auch.

Gruss - Peter

[Locke]

hi ihr zwei,
danke für eure Unterstützung und Vorschläge, ich werde mal versuchen es am WE zu testen, in der Woche schaffe ich es im moment nicht.

@Peter

Kann es sein, dass der Wert im Test-System vorher 0 oder kleiner als der Wert 1495.70 ?

nein, der gesetzte Wert war 1495.70 bei beiden Systemen (war der letze den ich gesetzt hatte). Ich wollte ihn auf 16520.57 ändern, was ja auch auf dem Testsystem klappte.